theory Lec04
  imports Main
begin

section {* Some Isar Basics *}

text {* Conjunctions *}

thm conjI[no_vars]

lemma
  assumes a: "P" "Q"
  shows "P \<and> Q"
using a by (auto)

lemma
  assumes a: "P" "Q"
  shows "P \<and> Q"
using a by (simp)

lemma
  assumes a: "P" "Q"
  shows "P \<and> Q"
using a by (blast)

text {* A detailed proof *}

lemma
  assumes a: "P" "Q"
  shows "P \<and> Q"
using a
proof -
  have "P" by fact
  moreover
  have "Q" by fact
  ultimately show "P \<and> Q" by (rule conjI)
qed
  
text {* Disjunction *}

thm disjI1

lemma
  assumes a: "P"
  shows "P \<or> Q"
proof -
  have "P" by fact
  then show "P \<or> Q" by (rule disjI1)
qed

text {* Compound Goals *}

lemma
  assumes a: "A" "B" "C"
  shows "(A \<and> B) \<and> C"
proof -
  have a: "C" by fact
  have "A" by fact
  moreover
  have "B" by fact
  ultimately 
  have "A \<and> B" by (rule conjI)
  then show "(A \<and> B) \<and> C" using a by (rule conjI)
qed

text {* Decomposing assumptions *}

thm conjunct1
thm conjunct2

text {* The order in which facts are chained is important *}

lemma 
  assumes a: "A \<and> B"
  shows "B \<and> A"
using a
proof -
  have a: "A \<and> B" by fact
  have "B" using a by (rule conjunct2)
  moreover
  have "A" using a by (rule conjunct1)
  ultimately
  show "B \<and> A" by (rule conjI)
qed


text {* The order in which facts are chained is important for rule. *}

lemma 
  assumes a: "A \<and> B"
  shows "B \<and> A"
using a
proof -
  have a: "A \<and> B" by fact
  have "A" using a by (rule conjunct1)
  moreover
  have "B" using a by (rule conjunct2)
  ultimately
  show "B \<and> A" proof - 
    thm conjI
    oops

text {* Implications *}

thm impI

lemma
  shows "A \<longrightarrow> A"
proof -
  { assume "A"
    then have "A" by assumption
  }
  then show "A \<longrightarrow> A" by (rule impI)
qed

text {* Notice the difference between \<Longrightarrow> and \<longrightarrow>: *}

lemma
  shows "A \<longrightarrow> A"
by (rule impI) (assumption)

lemma
  shows "A \<Longrightarrow> A"
by (assumption)

lemma
  assumes a: "A"
  shows "A"
using a by (assumption)

text {* Disjunctions are a special case of case distinctions. *}

lemma
  assumes a: "P \<or> Q"
  and     b1: "P \<Longrightarrow> C" and b2: "Q \<Longrightarrow> C"
  shows "C"
using a
proof -
  have "P \<or> Q" by fact
  moreover
  { assume "P"
    then have "C" by (rule b1)
  }
  moreover
  { assume "Q"
    then have "C" by (rule b2)
  }
  ultimately 
  show "C" by (rule disjE)
qed

text {* Again the order of chained facts is important *}

lemma
  assumes a: "P \<or> Q"
  and  b\<^isub>1: "P \<Longrightarrow> C" and b\<^isub>2: "Q \<Longrightarrow> C"
  shows "C"
using b\<^isub>1 b\<^isub>2 a oops


end